{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    systems.url = "github:nix-systems/x86_64-linux";
    flake-utils = {
      url = "github:numtide/flake-utils";
      inputs.systems.follows = "systems";
    };
  };
  outputs = {
    nixpkgs,
    flake-utils,
    ...
  }: let
    drv = {
      stdenv,
      lib,
      libX11,
      libXScrnSaver,
      dbus,
      pkg-config,
      ...
    }:
      stdenv.mkDerivation {
        pname = "sleeptimer";
        version = "0.0.1";
        src = lib.cleanSource ./.;
        nativeBuildInputs = [pkg-config];
        buildInputs = [libX11 libXScrnSaver dbus.dev];
        installPhase = ''
          mkdir -p $out/bin
          cp sleeptimer $out/bin
        '';
      };
  in
    flake-utils.lib.eachDefaultSystem (system: let
      pkgs = import nixpkgs {
        inherit system;
      };
      llvm = pkgs.llvmPackages_latest;
      package = pkgs.callPackage drv {inherit (llvm) stdenv;};
    in {
      devShells.default = pkgs.mkShell.override {inherit (llvm) stdenv;} {
        inputsFrom = [package];
        packages = with pkgs; [
          bear
          clang-tools
          zlib
          lzma
          icu74
        ];
      };
      packages = {
        default = package;
      };
    });
}